使用ImageMagick进行批量图片处理

hoebec · 发表于 2021-1-16 22:16:15

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？注册

x

本帖最后由 hoebec 于 2021-1-18 19:22 编辑

最近发现ImageMagick的自动脚本有时也挺方便的,发一些自己做的bat研究一下

因为是bat,所以都只支持单个文件和单层目录,没有递归(不会)

首先是基本的jpg转换和png转换:

@echo off
title Image-JPG
Setlocal Enabledelayedexpansion
Set str=%1
:str
if not defined str Set /p "str=Image file/folder:"
if not defined str goto str
dir /ad %str% >nul 2>nul&&goto dir||goto file
exit
:dir
if not exist !str!\ exit
echo convert image folder
cd /d %str%
Set qua=90
Set /p qua=compression ratio(default/90):
echo convert image files to jpg%qua% directory
if not exist %str%-jpg%qua% mkdir %str%-jpg%qua%
%~dp0\mogrify -path %str%-jpg%qua% -format jpg -quality %qua% *.*
Set /p exitinfo=done..
exit
:file
if not exist !str! exit
echo convert image file
Set qua=90
Set /p qua=compression ratio(default/90):
echo convert %str% to jpg%qua% file
for %%a in (!str!) do (
%~dp0\convert !str! -format jpg -quality %qua% "%%~dpna-jpg%qua%.jpg")
Set /p exitinfo=done..
exit

复制代码

@echo off
title Image-PNG
Setlocal Enabledelayedexpansion
Set str=%1
:str
if not defined str Set /p "str=Image file/folder:"
if not defined str goto str
dir /ad %str% >nul 2>nul&&goto dir||goto file
exit
:dir
if not exist !str!\ exit
echo convert image folder
cd /d %str%
Set qua=75
Set /p qua=compression level(default/75):
echo convert image files to png%qua% directory
if not exist %str%-png%qua% mkdir %str%-png%qua%
%~dp0\mogrify -path %str%-png%qua% -format png -quality %qua% *.*
Set /p exitinfo=done..
exit
:file
if not exist !str! exit
echo convert image file
Set qua=75
Set /p qua=compression level(default/75):
echo convert %str% to png%qua% file
for %%a in (!str!) do (
%~dp0\convert !str! -format png -quality %qua% "%%~dpna-png%qua%.png")
Set /p exitinfo=done..
exit

复制代码

使用方法:首先必须安装ImageMagick,官网下载https://www.imagemagick.org/script/download.php#windows.当然不用安装版的也可以,我自己用的是portable版(把exe文件复制到bat所在目录)
本贴的脚本都基于ImageMagick-7.0.10-57-portable-Q16-x64.zip版本制作

以上两个脚本需要用到convert.exe.双击运行bat,把需要转换的图片文件/文件夹拖到cmd窗口,ENTER,输入压缩质量数值,jpg是1-100,png是00-95(第一位数字取值0-9,第二位数字取值0-5),然后等待完成
会创建新文件/文件夹,不会修改原文件

图片缩放:

@echo off
title Image-Resize
Setlocal Enabledelayedexpansion
Set str=%1
:str
if not defined str Set /p "str=Image file/folder:"
if not defined str goto str
if not exist %str%\ goto file
:dir
echo resize image folder
cd /d %str%
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=quality(default/90):
Set rs=x1000
Set /p rs=image resize setting(1000/x1000,default/x1000):
if not exist %str%-%rs%-%ext%%qua% mkdir %str%-%rs%-%ext%%qua%
echo convert image files to %rs%-%ext%%qua% directory
%~dp0\mogrify -path %str%-%rs%-%ext%%qua% -resize %rs% -format %ext% -quality %qua% *.*
Set /p exitinfo=done..
exit
:file
if not exist %str% exit
echo resize image file
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=quality(default/90):
Set rs=x1000
Set /p rs=image resize setting(1000/x1000,default/x1000):
for %%a in (!str!) do (
echo convert %%~nxa to %rs%-%ext%%qua% file
%~dp0\convert !str! -resize %rs% -format %ext% -quality %qua% "%%~dpna-%rs%-%ext%%qua%.!ext!")
Set /p exitinfo=done..
exit

复制代码

ImageMagick的缩放参数比较多,基本的就是1000(1000宽)和x1000(1000高)这样的格式

图片旋转:

@echo off
title Image-Rotate
Setlocal Enabledelayedexpansion
Set str=%1
:str
if not defined str Set /p "str=Image file/folder:"
if not defined str goto str
if not exist %str%\ goto file
:dir
echo rotate image folder
cd /d %str%
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=quality(default/90):
Set bg=none
Set /p bg=background color(default/none):
Set rt=90
Set /p rt=image rotation degree(90/-90,default/90):
if not exist %str%-r%rt%-%ext%%qua% mkdir %str%-r%rt%-%ext%%qua%
echo convert image files to r%rt%-%ext%%qua% directory
%~dp0\mogrify -path %str%-r%rt%-%ext%%qua% -background %bg% -rotate %rt% -format %ext% -quality %qua% *.*
Set /p exitinfo=done..
exit
:file
if not exist %str% exit
echo rotate image file
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=quality(default/90):
Set bg=none
Set /p bg=background color(default/none):
Set rt=90
Set /p rt=image rotation degree(90/-90,default/90):
for %%a in (!str!) do (
echo convert %%~nxa to r%rt%-%ext%%qua% file
%~dp0\convert !str! -background %bg% -rotate %rt% -format %ext% -quality %qua% "%%~dpna-r%rt%-%ext%%qua%.!ext!")
Set /p exitinfo=done..
exit

复制代码

90,-90是旋转角度,这两种角度也不需要考虑背景色

批量加水印:

' 2>nul&cls&@echo off
' 2>nul&title Watermark
' 2>nul&Setlocal Enabledelayedexpansion
' 2>nul&Set /p "Input=Image file/folder:"
' 2>nul&Set /p "Water=Watermark txt/image:"
' 2>nul&start "" Wscript.exe %0 %Input% %Water% //Nologo //e:vbs &exit
Set objFSO = CreateObject("scripting.filesystemobject")
Set WshShell = CreateObject("Wscript.Shell")
Set RE = CreateObject("vbscript.RegExp")
Input = wscript.arguments(0)
Water = wscript.arguments(1)
Font="msyh.ttf"
Size=15
Color="red"
BgColor="none"
Width=300
Opacity=50
Ext="png"
Pos="-gravity southeast -geometry +25+25"
If LCase(objFSO.GetExtensionName(Water))="txt" Then
Font = Inputbox("Font Path:",,Font)
Size = Inputbox("Font Size:",,Size)
Color = Inputbox("Font Color:",,Color)
BgColor = Inputbox("Bg Color:",,BgColor)
Width = Inputbox("Watermark Width:",,Width)
End If
Opacity = Inputbox("Opacity:",,Opacity)
Ext = Inputbox("Output Ext:",,Ext)
Pos = Inputbox("Watermark Position:",,Pos)
If Font<>EMPTY Then FontPara="-font """&Font&""""
If Opacity<>EMPTY Then Compos="-compose dissolve -define compose:args="&Opacity
If objFSO.FileExists(Input) Then Output=objFSO.GetParentFolderName(Input)&"\"&objFSO.GetBaseName(Input)&"-watermarked."&Ext
If objFSO.FolderExists(Input) Then
Output=Input&"-watermarked"
If not objFSO.FolderExists(Output) Then objFSO.createFolder(Output)
End If
If LCase(objFSO.GetExtensionName(Water))="txt" Then
WatermarkImage=objFSO.GetSpecialFolder(2)&"\watermark.png"
WaterText=objFSO.OpenTextFile(Water,1,false,true).ReadAll
RE.Global = True
RE.MultiLine = True
RE.IgnoreCase = True
RE.Pattern = chr(34)
WaterText=RE.Replace(WaterText,chr(34)&chr(34))
RE.Pattern = chr(37)
WaterText=RE.Replace(WaterText,chr(37)&chr(37))
WshShell.run "convert -background """&Bgcolor&""" -fill """&Color&""" -pointsize "&Size&" -size "&Width&" "&FontPara&" caption:"""&WaterText&""" +antialias -flatten -trim "&WatermarkImage&"",0,true
Else
WatermarkImage=Water
End If
WaterSpace=objFSO.GetSpecialFolder(2)&"\colorspace"
If objFSO.FileExists(Input) Then
WatermarkImage=chr(34)&WatermarkImage&chr(34)
Input=chr(34)&Input&chr(34)
Output=chr(34)&Output&chr(34)
WshShell.Run "cmd /c identify -format %[colorspace] "&Input&">"&WaterSpace&"",0,true
CS="-colorspace "&objFSO.OpenTextFile(WaterSpace,1,false,false).ReadLine
WshShell.Run "composite "&CS&" "&Pos&" "&Compos&" "&WatermarkImage&" "&Input&" "&Output&"",0,true
objFSO.DeleteFile(WaterSpace)
CS=EMPTY
End If
If objFSO.FolderExists(Input) Then
WatermarkImage=chr(34)&WatermarkImage&chr(34)
For Each i in objFSO.GetFolder(Input).files
Inputfile=i.path
Outputfile=Output&"\"&objFSO.GetBaseName(i)&"."&Ext
Inputfile=chr(34)&Inputfile&chr(34)
Outputfile=chr(34)&Outputfile&chr(34)
WshShell.Run "cmd /c identify -format %[colorspace] "&Inputfile&">"&WaterSpace&"",0,true
CS="-colorspace "&objFSO.OpenTextFile(WaterSpace,1,false,false).ReadLine
WshShell.Run "composite "&CS&" "&Pos&" "&Compos&" "&WatermarkImage&" "&Inputfile&" "&Outputfile&"",0,true
objFSO.DeleteFile(WaterSpace)
CS=EMPTY
Next
End If
Wscript.Echo "Done"

复制代码

首先把需要加水印的图片文件/文件夹拖到cmd窗口,ENTER然后输入水印对应的txt/图片,如果输入的是图片,下一步就是在vbs里面依次选择(不)透明度,输出格式,水印位置(默认是右下角,距离边缘25像素).如果输入的是txt,就会读取txt的所有文本(按unicode编码读取),转换成一张水印图片,会增加文字的样式选择.
也一样是创建新文件,不修改原文件

转换截图文件:

@echo off
title ClipBoard-Image
Setlocal Enabledelayedexpansion
Set hour=%time:~0,2%
for /l %%i in (0,1,9) do (if %time:~0,2%==%%i Set hour=0%%i)
Set scrtime=%date:~0,4%%date:~5,2%%date:~8,2%_%hour%%time:~3,2%%time:~6,2%
Set scrfolder=%HOMEPATH%\Pictures\ScreenShot
if not exist %scrfolder% mkdir %scrfolder%
%~dp0\convert clipboard:myimage %scrfolder%\%scrtime%.png

复制代码

这个的用法是按下printscreen键后,双击运行脚本,就会在"我的图片\ScreenShot"目录下生成以时间数字命名的png截图

图片裁剪:

@echo off
title Image-crop
Setlocal Enabledelayedexpansion
Set str=%1
:str
if not defined str Set /p "str=Image file/folder:"
if not defined str goto str
choice /c:12 /m:"(1)edge crop (2)average crop"
if %errorlevel%==1 goto edgecrop
if %errorlevel%==2 goto averagecrop
:edgecrop
if not exist !str!\ goto filedge
echo edge crop image folder
cd /d "%str%"
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=compression ratio(default/90):
Set left=0
Set /p left=left crop(default/0):
Set right=0
Set /p right=right crop(default/0):
Set top=0
Set /p top=top crop(default/0):
Set bottom=0
Set /p bottom=bottom crop(default/0):
Set /a n=%left%+%right%+%top%+%bottom%
Set /a n1=%left%+%right%
Set /a n2=%top%+%bottom%
Set /a err=0
if !n! EQU 0 exit
if not exist %str%-c%left%-%right%-%top%-%bottom%-%ext%%qua% mkdir %str%-c%left%-%right%-%top%-%bottom%-%ext%%qua%
echo edge crop image files to c%left%-%right%-%top%-%bottom%-%ext%%qua% directory
for %%a in (*.*) do (
for /f %%i in ('%~dp0\identify -format %%w %%a') do Set w=%%i
for /f %%i in ('%~dp0\identify -format %%h %%a') do Set h=%%i
if !n1! GEQ !w! Set /a skip=1
if !n2! GEQ !h! Set /a skip=1
Set /a w1=!w!-!left!-!right!
Set /a h1=!h!-!top!-!bottom!
Set "newf=%str%-c%left%-%right%-%top%-%bottom%-%ext%%qua%\%%~na.!ext!"
if !skip! EQU 1 Set /a err=err+1
if !skip! NEQ 1 (
%~dp0\convert "%%a" -strip -crop !w1!x!h1!+!left!+!top! -format %ext% -quality %qua% "!newf!")
Set /a skip=0)
echo error: !err!
Set /p exitinfo=done..
exit
:filedge
if not exist !str! exit
echo edge crop image file
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=compression ratio(default/90):
Set left=0
Set /p left=left crop(default/0):
Set right=0
Set /p right=right crop(default/0):
Set top=0
Set /p top=top crop(default/0):
Set bottom=0
Set /p bottom=bottom crop(default/0):
Set /a n=%left%+%right%+%top%+%bottom%
Set /a n1=%left%+%right%
Set /a n2=%top%+%bottom%
Set /a err=0
if !n! EQU 0 exit
echo edge crop %%~nxa to c%left%-%right%-%top%-%bottom%-%ext%%qua% file
for %%a in (!str!) do (
for /f %%i in ('%~dp0\identify -format %%w %%a') do Set w=%%i
for /f %%i in ('%~dp0\identify -format %%h %%a') do Set h=%%i
if !n1! GEQ !w! Set /a skip=1
if !n2! GEQ !h! Set /a skip=1
Set /a w1=!w!-!left!-!right!
Set /a h1=!h!-!top!-!bottom!
Set "newf=%%~dpna-c%left%-%right%-%top%-%bottom%-%ext%%qua%.!ext!"
if !skip! EQU 1 Set /a err=err+1
if !skip! NEQ 1 (
%~dp0\convert "%%a" -strip -crop !w1!x!h1!+!left!+!top! -format %ext% -quality %qua% "!newf!")
Set /a skip=0)
echo error: !err!
Set /p exitinfo=done..
exit
:averagecrop
if not exist !str!\ goto fileaverage
echo average crop image folder
cd /d "%str%"
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=compression ratio(default/90):
Set drt=rtl
Set /p drt=direction(rtl/ltr,default/rtl):
if not exist %str%-%drt%-%ext%%qua% mkdir %str%-%drt%-%ext%%qua%
echo average crop image files to %drt%-%ext%%qua% directory
for %%a in (*.*) do (
for /f %%i in ('%~dp0\identify -format %%w "%%a"') do Set w=%%i
for /f %%i in ('%~dp0\identify -format %%h "%%a"') do Set h=%%i
Set /a w1=!w!/2
Set /a w2=!w!-!w1!
if "%drt%"=="ltr" Set "newf1=%str%-%drt%-%ext%%qua%\%%~na_1.!ext!"&Set "newf2=%str%-%drt%-%ext%%qua%\%%~na_2.!ext!"
if "%drt%"=="rtl" Set "newf1=%str%-%drt%-%ext%%qua%\%%~na_2.!ext!"&Set "newf2=%str%-%drt%-%ext%%qua%\%%~na_1.!ext!"
%~dp0\convert "%%a" -strip -crop !w1!x!h!+0+0 -format %ext% -quality %qua% "!newf1!"
%~dp0\convert "%%a" -strip -crop !w2!x!h!+!w1!+0 -format %ext% -quality %qua% "!newf2!")
Set /p exitinfo=done..
exit
:fileaverage
if not exist !str! exit
echo average crop image file
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=compression ratio(default/90):
Set drt=rtl
Set /p drt=direction(rtl/ltr,default/rtl):
for %%a in ("!str!") do (
echo average crop %%~nxa to %ext%%qua% file
for /f %%i in ('%~dp0\identify -format %%w "%%a"') do Set w=%%i
for /f %%i in ('%~dp0\identify -format %%h "%%a"') do Set h=%%i
Set /a w1=!w!/2
Set /a w2=!w!-!w1!
if "%drt%"=="ltr" Set "newf1=%%~dpna_1.!ext!"&Set "newf2=%%~dpna_2.!ext!"
if "%drt%"=="rtl" Set "newf1=%%~dpna_2.!ext!"&Set "newf2=%%~dpna_1.!ext!")
%~dp0\convert "!str!" -strip -crop !w1!x!h!+0+0 -format %ext% -quality %qua% "!newf1!"
%~dp0\convert "!str!" -strip -crop !w2!x!h!+!w1!+0 -format %ext% -quality %qua% "!newf2!"
Set /p exitinfo=done..
exit

复制代码

有两个选项,一个按边缘裁剪,另一个是水平方向平分为两张图片,这个脚本不支持带空格的文件路径

几何拼合图片:

@echo off
title Image-geometry
Setlocal Enabledelayedexpansion
Set str=%1
:str
if not defined str Set /p "str=Image file/folder:"
if not defined str goto str
if not exist %str%\ exit
cd /d %str%
Set ext=jpg
Set /p ext=new file type(default/jpg):
Set qua=90
Set /p qua=quality(default/90):
Set bg=none
Set /p bg=background color(default/none):
Set lati=1
Set /p lati=horizontal image number(default/1):
Set longi=1
Set /p longi=vertical image number(default/1):
echo geometry image files to %ext%%qua%-%lati%-%longi%.!ext!
for %%a in (!str!) do (
%~dp0\montage *.* -background %bg% -geometry +0+0 -tile %lati%x%longi% -format %ext% -quality %qua% "%%~dpna-%ext%%qua%-%lati%-%longi%.!ext!")
Set /p exitinfo=done..
exit

复制代码

按横向与竖向的设定数目拼合

定向去色:

@echo off
title Image-transparent
Setlocal Enabledelayedexpansion
Set str=%1
:str
if not defined str Set /p "str=Image file/folder:"
if not defined str goto str
dir /ad %str% >nul 2>nul&&goto dir||goto file
exit
:dir
if not exist !str!\ exit
echo convert image folder
cd /d %str%
Set color=white
Set /p color=discard color(default/white):
echo convert image files to transparent-%color% directory
if not exist %str%-transparent-%color% mkdir %str%-transparent-%color%
%~dp0\mogrify -path %str%-transparent-%color% -transparent %color% *.*
Set /p exitinfo=done..
exit
:file
if not exist !str! exit
echo convert image file
Set color=white
Set /p color=discard color(default/white):
for %%a in (!str!) do (
echo convert %%~nxa to transparent-%color% file
%~dp0\convert !str! -transparent %color% "%%~dpna-transparent-%color%.png")
Set /p exitinfo=done..
exit

复制代码

使某种颜色的区域变透明(假装可以批量去水印/抠图)

时差党 · 发表于 2021-1-16 22:19:07

有没有批量去水印的(逃)

Momus諾哪 · 发表于 2021-1-16 22:28:52

這裡有大神啊

hoebec · 发表于 2021-1-16 22:32:58

Momus諾哪发表于 2021-1-16 22:28
這裡有大神啊

网上的ImageMagick教程太多了,和FFMPEG一样都是应用相当广的,我也是勤劳的搬运工

虚魔顾客 · 发表于 2021-1-17 07:40:43

我都是bat直接建一个改名的

虚魔顾客 · 发表于 2021-1-17 08:46:41

大佬，直接把png重命名为jpg会有什么影响呢？

hoebec · 发表于 2021-1-17 08:56:31

虚魔顾客发表于 2021-1-17 08:46
大佬，直接把png重命名为jpg会有什么影响呢？

后缀名不会影响文件本身的性质.

看图软件也一般还是识别成png,我用的photoshop就无法加载

关键是,一般来说,同一张图片png转成jpg,文件会变小

虚魔顾客 · 发表于 2021-1-17 09:02:46

hoebec 发表于 2021-1-17 08:56
后缀名不会影响文件本身的性质.

看图软件也一般还是识别成png,我用的photoshop就无法加载

好的，谢谢哦。

no2body · 发表于 2021-1-17 11:55:52

反正低头就对了.jpg
我这边用ps，毕竟有时还要修图（
ps也有批量操作还行吧

ruidh · 发表于 2021-1-17 12:08:42

看呆了向大佬献上膝盖

pretear1314 · 发表于 2021-1-17 13:27:03

膜拜大神，我都是直接把png直接改成jpg
同问，有没批量去水印的方法，手残党用ps好慢

娼姬 · 发表于 2021-1-17 18:40:07

时差党发表于 2021-1-16 22:19
有没有批量去水印的(逃)

去水印是不可能去水印的:)，自动去水印只会毁图，如果水印都在统一位置空白处还好，不然只能手动去.....批量替换图源还比较现实....

时差党 · 发表于 2021-1-17 19:46:51

娼姬发表于 2021-1-17 18:40
去水印是不可能去水印的，自动去水印只会毁图，如果水印都在统一位置空白处还好，不然只能手动去..... ...

自己画呗哈哈哈哈哈哈...

ryokzend · 发表于 2021-1-17 23:10:32

哇大神！
我一直靠ffmpeg走天下（并没有
哎说起来去水印我都只能靠ps手动
练得一手嵌字修图的好本领（x）

		自动登录	找回密码
密码			注册

使用ImageMagick进行批量图片处理

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

评分

点评

点评

点评

版主御守

E·怠工组

天野远子·Epub组纪念章